Contract Diff Checker

Contract Name:
CanisterV2

Contract Source Code:

// SPDX-License-Identifier: MIT LICENSE
pragma solidity ^0.8.0;

import "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol";
import "@openzeppelin/contracts-upgradeable/access/OwnableUpgradeable.sol";
import "@openzeppelin/contracts-upgradeable/security/ReentrancyGuardUpgradeable.sol";
import "@openzeppelin/contracts-upgradeable/token/ERC20/IERC20Upgradeable.sol";
import "@openzeppelin/contracts-upgradeable/token/ERC20/utils/SafeERC20Upgradeable.sol";
import "@openzeppelin/contracts-upgradeable/utils/structs/EnumerableSetUpgradeable.sol";
import "@openzeppelin/contracts-upgradeable/token/ERC20/utils/SafeERC20Upgradeable.sol";

import "./ICanister.sol";
import "./ITreasury.sol";
import "./CanisterBase.sol";

contract CanisterV2 is
    Initializable,
    ICanister,
    OwnableUpgradeable,
    ReentrancyGuardUpgradeable,
    CanisterBase
{
    using EnumerableSetUpgradeable for EnumerableSetUpgradeable.AddressSet;
    using SafeERC20Upgradeable for IERC20Upgradeable;

    EnumerableSetUpgradeable.AddressSet private pools;

    modifier onlyAuthorized() {
        require(
            authorized[msg.sender] || owner() == msg.sender,
            "caller is not authorized"
        );
        _;
    }

    modifier poolExists(address poolToken) {
        require(pools.contains(poolToken), "Pool does not exist");
        _;
    }

    modifier canisterActive(address poolToken) {
        require(endTimestamp > block.timestamp, "Canister reward ended");
        _;
    }

    function initialize(
        address _boo,
        address _treasury,
        uint256 _totalReward,
        uint256 _startTimestamp,
        uint256 _endTimestamp,
        uint256 _initialUnlock,
        address _devaddr,
        uint256[] memory _withdrawalFees
    ) public initializer {
        __Ownable_init();
        __ReentrancyGuard_init();
        boo = IERC20Upgradeable(_boo);
        treasury = ITreasury(_treasury);
        startTimestamp = _startTimestamp;
        initialUnlock = _initialUnlock;
        totalReward = _totalReward;
        ratePerSecond = _totalReward / (_endTimestamp - _startTimestamp);
        devaddr = _devaddr;
        withdrawalFees = _withdrawalFees;
    }

    // View function to see pending $BOO on frontend.'
    // Add pendingRewards in each pool and claimed rewards in RewardInfo for accuracy
    function getPendingRewards(address _user, address[] memory poolTokens)
        public
        view
        returns (uint256)
    {
        uint256 reward = 0;
        for (uint256 i = 0; i < poolTokens.length; i++) {
            reward = reward + getPendingReward(_user, poolTokens[i]);
        }
        return reward;
    }

    // Returns pendingReward in a pool
    function getPendingReward(address _user, address poolToken)
        public
        view
        returns (uint256)
    {
        if (block.timestamp < startTimestamp) return 0;
        UserInfo storage user = userInfo[poolToken][_user];
        PoolInfo storage pool = poolInfo[poolToken];
        uint256 rewardPerShare = pool.rewardPerShare;

        if (block.timestamp > pool.lastRewardTimestamp && pool.balance > 0) {
            uint256 pendingReward = ratePerSecond *
                (block.timestamp - pool.lastRewardTimestamp);
            uint256 reward = (pendingReward * pool.allocPoint) /
                totalAllocPoint;
            rewardPerShare =
                rewardPerShare +
                ((reward * 1 ether) / pool.balance);
        }
        return ((user.amount * rewardPerShare) / 1 ether) - user.rewardDebt;
    }

    function updatePool(address poolToken) public poolExists(poolToken) {
        PoolInfo storage pool = poolInfo[poolToken];
        if (block.timestamp <= pool.lastRewardTimestamp) return;

        uint256 supply = pool.balance;
        if (supply == 0) {
            pool.lastRewardTimestamp = block.timestamp;
            return;
        }
        treasury.requestFund();
        uint256 pendingReward = ratePerSecond *
            (block.timestamp - pool.lastRewardTimestamp);
        uint256 reward = (pendingReward * pool.allocPoint) / totalAllocPoint;
        pool.rewardPerShare =
            pool.rewardPerShare +
            ((reward * 1 ether) / supply);
        pool.lastRewardTimestamp = block.timestamp;
        emit Update(poolToken, pool.rewardPerShare, pool.lastRewardTimestamp);
    }

    function _harvest(address poolToken) internal {
        PoolInfo storage pool = poolInfo[poolToken];
        UserInfo storage user = userInfo[poolToken][msg.sender];

        if (user.amount > 0) {
            uint256 pending = ((user.amount * pool.rewardPerShare) / 1 ether) -
                user.rewardDebt;
            if (pending > 0) {
                // boo.transfer(msg.sender, pending);
                // Reset the rewardDebtAtBlock to the current block for the user.
                RewardInfo storage _reward = rewardInfo[msg.sender];
                _reward.totalReward = _reward.totalReward + pending;
                _reward.reward += pending;
                user.rewardDebtAtTimestamp = block.timestamp;
                emit SendReward(msg.sender, poolToken, pending);
            }
            // Recalculate the rewardDebt for the user.
            user.rewardDebt = (user.amount * pool.rewardPerShare) / 1 ether;
        }
    }

    function getRewardInfo(address _user) public view returns (uint256) {
        return rewardInfo[_user].reward;
    }

    // User deposit tokens
    function deposit(
        address _user,
        address poolToken,
        uint256 amount
    ) public poolExists(poolToken) nonReentrant {
        UserInfo storage user = userInfo[poolToken][_user];
        PoolInfo storage pool = poolInfo[poolToken];
        IERC20Upgradeable token = IERC20Upgradeable(poolToken);
        // When a user deposits, we need to update the pool and harvest beforehand,
        // since the rates will change.
        updatePool(poolToken);
        _harvest(poolToken);

        token.safeTransferFrom(msg.sender, address(this), amount);
        user.amount += amount;
        user.totalDeposited += amount;
        pool.balance += amount;
        if (user.amount == 0) {
            user.rewardDebtAtTimestamp = block.timestamp;
        }
        user.rewardDebt = (user.amount * pool.rewardPerShare) / 1 ether;
        if (user.firstDepositTimestamp > 0) {} else {
            user.firstDepositTimestamp = block.timestamp;
        }
        user.lastDepositTimestamp = block.timestamp;
        emit Deposit(_user, poolToken, amount);
    }

    function addRewardToUser(address _user, uint256 amount)
        external
        onlyAuthorized
    {
        RewardInfo storage _reward = rewardInfo[msg.sender];
        _reward.totalReward = _reward.totalReward + amount;
        _reward.reward += amount;
        emit RewardAddedToUser(msg.sender, _user, amount);
    }

    function claimRewards(address[] memory poolTokens) public {
        for (uint256 i = 0; i < poolTokens.length; i++) {
            updatePool(poolTokens[i]);
            _harvest(poolTokens[i]);
        }
        RewardInfo storage user = rewardInfo[msg.sender];
        // uint256 amount = user.totalReward;
        uint256 amount = getUnlocked(
            user.reward,
            user.totalReward,
            user.totalClaimed
        );

        if (pools.contains(address(boo))) {
            if (
                amount >
                boo.balanceOf(address(this)) - poolInfo[address(boo)].balance
            ) {
                amount =
                    boo.balanceOf(address(this)) -
                    poolInfo[address(boo)].balance;
            }
        } else {
            if (amount > boo.balanceOf(address(this))) {
                amount = boo.balanceOf(address(this));
            }
        }

        user.reward -= amount;
        user.totalClaimed += amount;
        boo.safeTransfer(msg.sender, amount);
        emit RewardClaimed(msg.sender, amount);
    }

    function getWithdrawable(address _user, address[] memory poolTokens)
        public
        view
        returns (uint256)
    {
        uint256 amount;
        for (uint256 i = 0; i < poolTokens.length; i++) {
            UserInfo storage user = userInfo[poolTokens[i]][_user];
            amount += getUnlocked(
                user.amount,
                user.totalDeposited,
                user.totalWithdrawn
            );
        }
        return amount;
    }

    function getClaimable(address _user) public view returns (uint256) {
        RewardInfo storage user = rewardInfo[_user];
        return getUnlocked(user.reward, user.totalReward, user.totalClaimed);
    }

    function getLockedReward(address _user) public view returns (uint256) {
        RewardInfo storage user = rewardInfo[_user];
        return
            user.reward -
            getUnlocked(user.reward, user.totalReward, user.totalClaimed);
    }

    // Returns unlocked token amount that users can withdraw
    function getUnlocked(
        uint256 current,
        uint256 total,
        uint256 claimed
    ) public view returns (uint256) {
        if (block.timestamp < startTimestamp) {
            return 0;
        } else if (block.timestamp >= endTimestamp) {
            return current;
        }
        uint256 releaseBlock = block.timestamp - startTimestamp;
        uint256 totalLockedBlock = endTimestamp - startTimestamp;
        uint256 initialUnlockScale = 100 - initialUnlock;
        uint256 unlockedTotalDeposited = (total *
            (((releaseBlock * 1e5 * initialUnlockScale) /
                totalLockedBlock /
                100) + ((initialUnlock * 1e5) / 100))) / 1e5;
        if (claimed >= total) return 0;
        else return unlockedTotalDeposited - claimed;
    }

    // User withdraws tokens from respective token pools
    function withdraw(
        address _user,
        address poolToken,
        uint256 amount
    ) public poolExists(poolToken) nonReentrant {
        require(msg.sender == _user, "Only owner can withdraw");
        UserInfo storage user = userInfo[poolToken][_user];
        PoolInfo storage pool = poolInfo[poolToken];
        require(
            amount <=
                getUnlocked(
                    user.amount,
                    user.totalDeposited,
                    user.totalWithdrawn
                ),
            "Given amount is not unlocked yet"
        );
        updatePool(poolToken);
        _harvest(poolToken);
        if (amount > 0) {
            user.amount = user.amount - amount;
            if (user.lastWithdrawTimestamp > 0) {
                user.timestampDelta =
                    block.timestamp -
                    user.lastWithdrawTimestamp;
            } else {
                user.timestampDelta =
                    block.timestamp -
                    user.firstDepositTimestamp;
            }
            //25% fee for withdrawals of tokens in the same block to prevent abuse from flashloans
            if (
                user.timestampDelta == withdrawalFees[0] ||
                block.timestamp == user.lastWithdrawTimestamp
            ) {
                uint256 fees = (amount * 25) / 100;
                pool.token.transfer(msg.sender, amount - fees);
                pool.token.transfer(address(devaddr), fees);
            } else if (
                user.timestampDelta > withdrawalFees[0] &&
                user.timestampDelta <= withdrawalFees[1]
            ) {
                //10% fee if a user deposits and withdraws in between same block and 59 minutes.
                uint256 fees = (amount * 10) / 100;
                pool.token.safeTransfer(msg.sender, amount - fees);
                pool.token.safeTransfer(address(devaddr), fees);
            } else {
                pool.token.transfer(msg.sender, amount);
            }
            user.rewardDebt = (user.amount * pool.rewardPerShare) / 1 ether;
            user.lastWithdrawTimestamp = block.timestamp;
            pool.balance -= amount;
            user.totalWithdrawn += amount;
            emit Withdraw(msg.sender, poolToken, amount);
        }
    }

    function getCurrentLockedRate() public view returns (uint256) {
      if (block.timestamp < startTimestamp) {
            return 0;
      } else if (block.timestamp >= endTimestamp) {
          return 100;
      }
      uint256 releaseBlock = block.timestamp - startTimestamp;
      uint256 totalLockedBlock = endTimestamp - startTimestamp;
      uint256 initialUnlockScale = 100 - initialUnlock;
      return  (((releaseBlock * 1e5 * initialUnlockScale) /
              totalLockedBlock /
              100) + ((initialUnlock * 1e5) / 100)) / 1e5;
    }

    function addPool(address poolToken, uint256 _allocPoint)
        public
        onlyAuthorized
    {
        require(
            pools.contains(poolToken) == false,
            "Token already allocated for canister"
        );
        totalAllocPoint += _allocPoint;
        uint256 lastRewardTimestamp = block.timestamp > startTimestamp
            ? block.timestamp
            : startTimestamp;
        if (pools.add(poolToken)) {
            poolInfo[poolToken] = PoolInfo({
                token: IERC20Upgradeable(poolToken),
                allocPoint: _allocPoint,
                balance: 0,
                lastRewardTimestamp: lastRewardTimestamp,
                rewardPerShare: 0
            });
            emit PoolAdded(poolToken, _allocPoint);
        }
    }

    function setPool(address poolToken, uint256 _allocPoint)
        public
        onlyAuthorized
        poolExists(poolToken)
    {
        totalAllocPoint =
            totalAllocPoint -
            poolInfo[poolToken].allocPoint +
            _allocPoint;
        poolInfo[poolToken].allocPoint = _allocPoint;
        emit PoolUpdated(poolToken, _allocPoint);
    }

    function removePool(address poolToken)
        external
        virtual
        onlyAuthorized
        poolExists(poolToken)
    {
        if (poolInfo[poolToken].balance == 0 && pools.remove(poolToken)) {
            totalAllocPoint -= poolInfo[poolToken].allocPoint;
            delete poolInfo[poolToken];
            emit PoolRemoved(poolToken);
        }
    }

    function poolLength() external view returns (uint256) {
        return pools.length();
    }

    function getPoolBalance(address poolToken) public view returns (uint256) {
        return poolInfo[poolToken].balance;
    }

    function getUserBalance(address poolToken, address _user)
        public
        view
        returns (uint256)
    {
        return userInfo[poolToken][_user].amount;
    }

    function addAuthorized(address _toAdd) public onlyOwner {
        authorized[_toAdd] = true;
    }

    function removeAuthorized(address _toRemove) public onlyOwner {
        require(_toRemove != msg.sender);
        authorized[_toRemove] = false;
    }

    function setInitialUnlock(uint256 _initialUnlock) public onlyAuthorized {
        require(_initialUnlock < 100);
        initialUnlock = _initialUnlock;
    }

    function updateTimestamp(uint256 _startTimestamp, uint256 _endTimestamp)
        external
        onlyAuthorized
    {
        if (_startTimestamp > 0) {
            startTimestamp = _startTimestamp;
        }

        if (_endTimestamp > 0) {
            require(
                _endTimestamp > _startTimestamp,
                "Rewards must last > 1 sec"
            );
            require(
                _endTimestamp > block.timestamp,
                "Cannot end rewards in the past"
            );

            endTimestamp = _endTimestamp;
        }

        ratePerSecond = totalReward / (endTimestamp - startTimestamp);
    }

    function setTotalReward(uint256 amount) external onlyAuthorized {
        totalReward = amount;
        ratePerSecond = totalReward / (endTimestamp - startTimestamp);
    }

    function setWithdrawalFeeStages(uint256[] memory _userFees)
        public
        onlyAuthorized
    {
        withdrawalFees = _userFees;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

import '@openzeppelin/contracts-upgradeable/token/ERC20/IERC20Upgradeable.sol';


interface ITreasury {
    struct StreamInfo {
        uint256 totalFund;
        uint256 startTimestamp;
        uint256 endTimestamp;
        uint256 lastPullTimestamp;
        uint256 ratePerSecond;
        uint256 funded;
    }
    
    function requestFund() external returns (uint256 rewardsPaid);

    function grantTokenToStream(address _stream, uint256 _amount) external;

    function getStreams() external view returns (address[] memory);

    function getStreamInfo(address _stream) external view returns (StreamInfo memory);

    function getGlobalRatePerSecond() external view returns (uint256 globalRatePerSecond);

    function getRatePerSecond(address _stream) external view returns (uint256 ratePerSecond);

    function getPendingFund(address _stream) external view returns (uint256 pendingFund);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

import '@openzeppelin/contracts-upgradeable/token/ERC20/IERC20Upgradeable.sol';

interface ICanister {
  struct UserInfo {
    uint256 amount; // How many tokens the user has provided.
    uint256 lastWithdrawTimestamp; // the last Timestamp a user withdrew at.
    uint256 firstDepositTimestamp; // the first Timestamp a user deposited at.
    uint256 lastDepositTimestamp; // the last Timestamp user depostied at.
    uint256 totalDeposited;
    uint256 totalWithdrawn;
    uint256 rewardDebt;
    uint256 rewardDebtAtTimestamp; // the last Timestamp user stake
    uint256 timestampDelta;
  }

  struct RewardInfo {
    uint256 lastClaimedTimestamp;
    uint256 totalReward;
    uint256 reward;
    uint256 totalClaimed;
  }

  // Info of each pool.
  struct PoolInfo {
    IERC20Upgradeable token; // Address of token contract (BOO, MAGIC, BOO-MAGIC, etc)
    uint256 allocPoint; // How many points are assigned to this pool.
    uint256 balance; // Total tokens locked up
    uint256 rewardPerShare;
    uint256 lastRewardTimestamp;
  }

  // View function to see pending $BOO on frontend.'
  // Add pendingRewards in each pool and claimed rewards in RewardInfo for accuracy
  function getPendingRewards(address _user, address[] memory poolTokens) external view returns (uint256);

  function updatePool(address poolToken) external;

  function getRewardInfo(address _user) external view returns (uint256);

  // User deposit tokens
  function deposit(address _user, address poolToken, uint256 amount) external;
  
  // User withdraws tokens from respective token pools
  function withdraw(address _user, address poolToken, uint256 amount) external;

  function claimRewards(address[] memory poolTokens) external;

  function getWithdrawable(address _user, address[] memory poolTokens) external view returns (uint256);

  function getClaimable(address _user) external view returns (uint256);

  function getLockedReward(address _user) external view returns (uint256);
}

// SPDX-License-Identifier: MIT LICENSE
pragma solidity ^0.8.0;

import "./ITreasury.sol";
import '@openzeppelin/contracts-upgradeable/token/ERC20/IERC20Upgradeable.sol';
import "./ICanister.sol";
import '@openzeppelin/contracts-upgradeable/utils/structs/EnumerableSetUpgradeable.sol';


contract CanisterBase {
  mapping(address => bool) public authorized;
  ITreasury treasury;
  uint256 public totalReward;
  uint256 public startTimestamp;
  uint256 public endTimestamp;
  uint256 public ratePerSecond;

  IERC20Upgradeable public boo;
  // Owner address; Withdrawal fees would go to this address
  address public devaddr;

  uint256 public totalAllocPoint;

  uint256 public initialUnlock; // In percentage, e.g 25 for 25%

  uint256[] public withdrawalFees;

  mapping (address => ICanister.PoolInfo) public poolInfo;

  // poolTokenAddress => userAddress => UserInfo
  mapping(address => mapping(address => ICanister.UserInfo)) public userInfo; // poolId => userAddress => UserInfo
  mapping(address => ICanister.RewardInfo) public rewardInfo; // userAddress => RewardInfo

  event Update(address indexed poolToken, uint256 rewardPerShare, uint256 lastRewardBlock);
  event FundDifference(address indexed poolToken, uint256 blockTimestamp, uint256 lastRewardTimestamp, uint256 pulledFund, uint256 pendingReward);
  event Deposit(address indexed user, address indexed poolToken, uint256 amount);
  event SendReward(address indexed user, address indexed poolToken, uint256 reward);
  event RewardClaimed(address indexed user, uint256 reward);
  event Withdraw(address indexed user, address indexed poolToken, uint256 amount);
  event PoolAdded(address indexed poolToken, uint256 allocPoint);
  event PoolUpdated(address indexed poolToken, uint256 allocPoint);
  event PoolRemoved(address indexed poolToken);
  event RewardAddedToUser(address indexed sender, address indexed receiver, uint256 amount);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/structs/EnumerableSet.sol)

pragma solidity ^0.8.0;

/**
 * @dev Library for managing
 * https://en.wikipedia.org/wiki/Set_(abstract_data_type)[sets] of primitive
 * types.
 *
 * Sets have the following properties:
 *
 * - Elements are added, removed, and checked for existence in constant time
 * (O(1)).
 * - Elements are enumerated in O(n). No guarantees are made on the ordering.
 *
 * ```
 * contract Example {
 *     // Add the library methods
 *     using EnumerableSet for EnumerableSet.AddressSet;
 *
 *     // Declare a set state variable
 *     EnumerableSet.AddressSet private mySet;
 * }
 * ```
 *
 * As of v3.3.0, sets of type `bytes32` (`Bytes32Set`), `address` (`AddressSet`)
 * and `uint256` (`UintSet`) are supported.
 */
library EnumerableSetUpgradeable {
    // To implement this library for multiple types with as little code
    // repetition as possible, we write it in terms of a generic Set type with
    // bytes32 values.
    // The Set implementation uses private functions, and user-facing
    // implementations (such as AddressSet) are just wrappers around the
    // underlying Set.
    // This means that we can only create new EnumerableSets for types that fit
    // in bytes32.

    struct Set {
        // Storage of set values
        bytes32[] _values;
        // Position of the value in the `values` array, plus 1 because index 0
        // means a value is not in the set.
        mapping(bytes32 => uint256) _indexes;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function _add(Set storage set, bytes32 value) private returns (bool) {
        if (!_contains(set, value)) {
            set._values.push(value);
            // The value is stored at length-1, but we add 1 to all indexes
            // and use 0 as a sentinel value
            set._indexes[value] = set._values.length;
            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function _remove(Set storage set, bytes32 value) private returns (bool) {
        // We read and store the value's index to prevent multiple reads from the same storage slot
        uint256 valueIndex = set._indexes[value];

        if (valueIndex != 0) {
            // Equivalent to contains(set, value)
            // To delete an element from the _values array in O(1), we swap the element to delete with the last one in
            // the array, and then remove the last element (sometimes called as 'swap and pop').
            // This modifies the order of the array, as noted in {at}.

            uint256 toDeleteIndex = valueIndex - 1;
            uint256 lastIndex = set._values.length - 1;

            if (lastIndex != toDeleteIndex) {
                bytes32 lastvalue = set._values[lastIndex];

                // Move the last value to the index where the value to delete is
                set._values[toDeleteIndex] = lastvalue;
                // Update the index for the moved value
                set._indexes[lastvalue] = valueIndex; // Replace lastvalue's index to valueIndex
            }

            // Delete the slot where the moved value was stored
            set._values.pop();

            // Delete the index for the deleted slot
            delete set._indexes[value];

            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function _contains(Set storage set, bytes32 value) private view returns (bool) {
        return set._indexes[value] != 0;
    }

    /**
     * @dev Returns the number of values on the set. O(1).
     */
    function _length(Set storage set) private view returns (uint256) {
        return set._values.length;
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function _at(Set storage set, uint256 index) private view returns (bytes32) {
        return set._values[index];
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function _values(Set storage set) private view returns (bytes32[] memory) {
        return set._values;
    }

    // Bytes32Set

    struct Bytes32Set {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(Bytes32Set storage set, bytes32 value) internal returns (bool) {
        return _add(set._inner, value);
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(Bytes32Set storage set, bytes32 value) internal returns (bool) {
        return _remove(set._inner, value);
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(Bytes32Set storage set, bytes32 value) internal view returns (bool) {
        return _contains(set._inner, value);
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(Bytes32Set storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(Bytes32Set storage set, uint256 index) internal view returns (bytes32) {
        return _at(set._inner, index);
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(Bytes32Set storage set) internal view returns (bytes32[] memory) {
        return _values(set._inner);
    }

    // AddressSet

    struct AddressSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(AddressSet storage set, address value) internal returns (bool) {
        return _add(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(AddressSet storage set, address value) internal returns (bool) {
        return _remove(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(AddressSet storage set, address value) internal view returns (bool) {
        return _contains(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(AddressSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(AddressSet storage set, uint256 index) internal view returns (address) {
        return address(uint160(uint256(_at(set._inner, index))));
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(AddressSet storage set) internal view returns (address[] memory) {
        bytes32[] memory store = _values(set._inner);
        address[] memory result;

        assembly {
            result := store
        }

        return result;
    }

    // UintSet

    struct UintSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(UintSet storage set, uint256 value) internal returns (bool) {
        return _add(set._inner, bytes32(value));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(UintSet storage set, uint256 value) internal returns (bool) {
        return _remove(set._inner, bytes32(value));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(UintSet storage set, uint256 value) internal view returns (bool) {
        return _contains(set._inner, bytes32(value));
    }

    /**
     * @dev Returns the number of values on the set. O(1).
     */
    function length(UintSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(UintSet storage set, uint256 index) internal view returns (uint256) {
        return uint256(_at(set._inner, index));
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(UintSet storage set) internal view returns (uint256[] memory) {
        bytes32[] memory store = _values(set._inner);
        uint256[] memory result;

        assembly {
            result := store
        }

        return result;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;
import "../proxy/utils/Initializable.sol";

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract ContextUpgradeable is Initializable {
    function __Context_init() internal onlyInitializing {
    }

    function __Context_init_unchained() internal onlyInitializing {
    }
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[50] private __gap;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library AddressUpgradeable {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verifies that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20Upgradeable.sol";
import "../../../utils/AddressUpgradeable.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20Upgradeable {
    using AddressUpgradeable for address;

    function safeTransfer(
        IERC20Upgradeable token,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    function safeTransferFrom(
        IERC20Upgradeable token,
        address from,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(
        IERC20Upgradeable token,
        address spender,
        uint256 value
    ) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    function safeIncreaseAllowance(
        IERC20Upgradeable token,
        address spender,
        uint256 value
    ) internal {
        uint256 newAllowance = token.allowance(address(this), spender) + value;
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    function safeDecreaseAllowance(
        IERC20Upgradeable token,
        address spender,
        uint256 value
    ) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            uint256 newAllowance = oldAllowance - value;
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20Upgradeable token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address.functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        if (returndata.length > 0) {
            // Return data is optional
            require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20Upgradeable {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;
import "../proxy/utils/Initializable.sol";

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuardUpgradeable is Initializable {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    function __ReentrancyGuard_init() internal onlyInitializing {
        __ReentrancyGuard_init_unchained();
    }

    function __ReentrancyGuard_init_unchained() internal onlyInitializing {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        // On the first call to nonReentrant, _notEntered will be true
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;

        _;

        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[49] private __gap;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (proxy/utils/Initializable.sol)

pragma solidity ^0.8.0;

import "../../utils/AddressUpgradeable.sol";

/**
 * @dev This is a base contract to aid in writing upgradeable contracts, or any kind of contract that will be deployed
 * behind a proxy. Since proxied contracts do not make use of a constructor, it's common to move constructor logic to an
 * external initializer function, usually called `initialize`. It then becomes necessary to protect this initializer
 * function so it can only be called once. The {initializer} modifier provided by this contract will have this effect.
 *
 * TIP: To avoid leaving the proxy in an uninitialized state, the initializer function should be called as early as
 * possible by providing the encoded function call as the `_data` argument to {ERC1967Proxy-constructor}.
 *
 * CAUTION: When used with inheritance, manual care must be taken to not invoke a parent initializer twice, or to ensure
 * that all initializers are idempotent. This is not verified automatically as constructors are by Solidity.
 *
 * [CAUTION]
 * ====
 * Avoid leaving a contract uninitialized.
 *
 * An uninitialized contract can be taken over by an attacker. This applies to both a proxy and its implementation
 * contract, which may impact the proxy. To initialize the implementation contract, you can either invoke the
 * initializer manually, or you can include a constructor to automatically mark it as initialized when it is deployed:
 *
 * [.hljs-theme-light.nopadding]
 * ```
 * /// @custom:oz-upgrades-unsafe-allow constructor
 * constructor() initializer {}
 * ```
 * ====
 */
abstract contract Initializable {
    /**
     * @dev Indicates that the contract has been initialized.
     */
    bool private _initialized;

    /**
     * @dev Indicates that the contract is in the process of being initialized.
     */
    bool private _initializing;

    /**
     * @dev Modifier to protect an initializer function from being invoked twice.
     */
    modifier initializer() {
        // If the contract is initializing we ignore whether _initialized is set in order to support multiple
        // inheritance patterns, but we only do this in the context of a constructor, because in other contexts the
        // contract may have been reentered.
        require(_initializing ? _isConstructor() : !_initialized, "Initializable: contract is already initialized");

        bool isTopLevelCall = !_initializing;
        if (isTopLevelCall) {
            _initializing = true;
            _initialized = true;
        }

        _;

        if (isTopLevelCall) {
            _initializing = false;
        }
    }

    /**
     * @dev Modifier to protect an initialization function so that it can only be invoked by functions with the
     * {initializer} modifier, directly or indirectly.
     */
    modifier onlyInitializing() {
        require(_initializing, "Initializable: contract is not initializing");
        _;
    }

    function _isConstructor() private view returns (bool) {
        return !AddressUpgradeable.isContract(address(this));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/ContextUpgradeable.sol";
import "../proxy/utils/Initializable.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract OwnableUpgradeable is Initializable, ContextUpgradeable {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    function __Ownable_init() internal onlyInitializing {
        __Ownable_init_unchained();
    }

    function __Ownable_init_unchained() internal onlyInitializing {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[49] private __gap;
}

Please enter a contract address above to load the contract details and source code.

Context size (optional):